2011-11-1 求嵌套表平均值

http://www.itpub.net/thread-1499223-11-1.html

101楼 我创建了一个SCHEMA级别的NUMBER型嵌套表：

CREATE OR REPLACE TYPE plch_numbers_t IS TABLE OF NUMBER
/

哪些选项实现了一个名字为plch_avg的函数，能够计算一个上述嵌套表中所有元素的平均值，从而使得下列代码块执行之后会显示"3.5"?

DECLARE
   l_numbers   plch_numbers_t
                  := plch_numbers_t (1, 2, 3, 4, 5, 6);
BEGIN
   DBMS_OUTPUT.put_line (plch_avg (l_numbers));
END;
/

(A)

CREATE OR REPLACE FUNCTION plch_avg (numbers_in IN plch_numbers_t)
   RETURN NUMBER
IS
   l_index   PLS_INTEGER := numbers_in.FIRST;
   l_sum     NUMBER := 0;
BEGIN
   WHILE l_index IS NOT NULL
   LOOP
      l_sum := l_sum + numbers_in (l_index);
      l_index := numbers_in.NEXT (l_index);
   END LOOP;
   RETURN l_sum / numbers_in.COUNT;
END;
/

(B)

CREATE OR REPLACE FUNCTION plch_avg (numbers_in IN plch_numbers_t)
   RETURN NUMBER
IS
   l_average   NUMBER;
BEGIN
   SELECT AVG (COLUMN_VALUE) INTO l_average
     FROM TABLE (numbers_in);
   RETURN l_average;
END;
/

(C)

CREATE OR REPLACE FUNCTION plch_avg (numbers_in IN plch_numbers_t)
   RETURN NUMBER
IS
BEGIN
   RETURN AVG (numbers_in);
END;
/

(D)

CREATE OR REPLACE FUNCTION plch_avg (numbers_in IN plch_numbers_t)
   RETURN NUMBER
IS
   l_index   PLS_INTEGER := numbers_in.FIRST;
   l_average     NUMBER := 0;
BEGIN
   WHILE l_index IS NOT NULL
   LOOP
      l_average := l_average + numbers_in (l_index)/numbers_in.count;
      l_index := numbers_in.NEXT (l_index);
   END LOOP;
   RETURN l_average;
END;
/

(E)

CREATE OR REPLACE FUNCTION plch_avg (numbers_in IN plch_numbers_t)
   RETURN NUMBER
IS
   l_average   NUMBER;
BEGIN
   SELECT AVG (numbers_in(ROWNUM)) INTO l_average
     FROM numbers_in;
   RETURN l_average;
END;
/

实测答案ABCC报错 PLS-00204: 函数或伪列 'AVG' 只能在 SQL 语句中使用E报错 PL/SQL: ORA-00942: 表或视图不存在 答案105楼2011-11-1 答案ABD, B是最佳答案，注意D在某些情况下可能出现误差。